Sugar Valley NeoPool Controller~

Template {"NAME":"NeoPool","GPIO":[0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,1,1,1,0,0,6976,0,0,0,0,0,7008,1,0,0,0,0,0,0],"FLAG":0,"BASE":1}

{
  "Time": "2021-06-01T11:00:00+02:00",
  "NeoPool": {
    "Time": "2021-06-01T11:00:00",
    "Type": "Oxilife",
    "Module": {
      "pH": 1,
      "Redox": 1,
      "Hydrolysis": 1,
      "Chlorine": 1,
      "Conductivity": 1,
      "Ionization": 1
    },
    "Temperature": 23.5,
    "Powerunit": {
      "Version": "V3.45",
      "NodeID": "XXXX XXXX XXXX XXXX XXXX 442A",
      "5V": 5.017,
      "12V": 13.904,
      "24-30V": 33.721,
      "4-20mA": 0.01
    },
    "pH": {
      "Data": 7.2,
      "Min": 7.0,
      "Max": 7.2,
      "State": 0,
      "Pump": 2,
      "FL1": 0,
      "Tank": 1
    },
    "Redox": {
      "Data": 752,
      "Setpoint": 750
    },
    "Chlorine": {
      "Data": 0.7,
      "Setpoint": 1.0
    },
    "Conductivity": 0,
    "Ionization": {
      "Data": 0,
      "Setpoint": 0,
      "Max": 0
    },
    "Hydrolysis": {
      "Data": 100,
      "Unit": "%",
      "Setpoint": 100,
      "Max": 100,
      "Runtime": {
        "Total": "28T22:13:19",
        "Part": "28T22:13:02",
        "Pol1": "14T12:32:46",
        "Pol2": "14T09:40:33",
        "Changes": 258
      },
      "State": "Pol1",
      "Cover": 0,
      "Boost": 0,
      "Low": 0
    },
    "Filtration": {
      "State": 1,
      "Speed": 2,
      "Mode": 1
    },
    "Light": 0,
    "Relay": {
      "State": [0, 1, 0, 0, 0, 1, 0],
      "Aux": [0, 0, 1, 0],
      "Acid": 0
    }
  },
  "TempUnit": "C"
}

{
  "Modules": {
    "pH": 1,
    "Redox": 1,
    "Hydrolysis": 1,
    "Chlorine": 0,
    "Conductivity": 0,
    "Ionization": 0
  },
  "Relay": {
    "Acid": 1,
    "Base": 0,
    "Redox": 0,
    "Chlorine": 0,
    "Conductivity": 0,
    "Heating": 4,
    "UV": 0,
    "Valve": 0
  }
}

NPFiltrationmode
RESULT = {"NPFiltrationmode":"Manual"}

NPFiltrationmode 1
{"NPFiltrationmode":"Auto"}

NPLight 1
RESULT = {"NPLight":"ON"}

Backlog NPResult 0;NPRead 0x416
RESULT = {"NPResult":0}
RESULT = {"NPRead":{"Address":1046,"Data":28}}

Backlog NPBit 0x605,15,1;NPSave
RESULT = {"NPBit":{"Address":"0x0605","Data":"0xAFC0","Bit15":1}}
RESULT = {"NPSave":"Done"}

Backlog NPResult 0;NPTime;NPReadL 0x408
RESULT = {"NPResult":0}
RESULT = {"NPTime":"2021-01-31T21:22:20"}
RESULT = {"NPReadL":{"Address":1032,"Data":1612124540}}

Backlog NPWrite 0x40F,1;NPSave
RESULT = {"NPWrite":{"Address":"0x040F","Data":"0x0001"}}
RESULT = {"NPSave":"Done"}

NPBit 0x605,3,1
RESULT = {"NPBit":{"Address":"0x0605","Data":"0x08C8"}}

Backlog NPResult 0;NPRead 0x434;NPReadL 0x435,7;NPRead 0x443;NPReadL 0x444,7;NPRead 0x452;NPReadL 0x0453,7
RESULT = {"NPResult":0}
RESULT = {"NPRead":{"Address":1076,"Data":1}}
RESULT = {"NPReadL":{"Address":1077,"Data":[28800,0,86400,14400,0,1,0]}}
RESULT = {"NPRead":{"Address":1091,"Data":1}}
RESULT = {"NPReadL":{"Address":1092,"Data":[43200,0,86400,21600,0,1,0]}}
RESULT = {"NPRead":{"Address":1106,"Data":1}}
RESULT = {"NPReadL":{"Address":1107,"Data":[0,0,86400,0,0,1,0]}} *

NPWriteL 0x435,32400 0 86400 12600
RESULT = {"NPWriteL":{"Address":1077,"Data":[32400,0,86400,12600]}}

Backlog NPWrite 0x4D9,3;NPExec
RESULT = {"NPWrite":{"Address":"0x04D9","Data":"0x0003"}}
RESULT = {"NPExec":"Done"}

Backlog NPWrite 0x4D9,4;NPExec
RESULT = {"NPWrite":{"Address":"0x04D9","Data":"0x0004"}}
RESULT = {"NPExec":"Done"}

NPOnError
RESULT = {"NPOnError":2}

NPOnError 3
RESULT = {"NPOnError":3}

Rule2
  ON Clock#Timer=10 DO NPTime 0 ENDON

Backlog Rule2 4;Rule2 1

Backlog GPIO0 224;GPIO4 225

Backlog WebButton1 Filtration;WebButton2 Light

Rule1
  ON Power1#State==0 DO NPFiltration %value% ENDON
  ON Power1#State==1 DO NPFiltration %value% ENDON
  ON NeoPool#Filtration#State==0 DO Power1 %value% ENDON
  ON NeoPool#Filtration#State==1 DO Power1 %value% ENDON
  ON Power2#State==0 DO NPLight %value% ENDON
  ON Power2#State==1 DO NPLight %value% ENDON
  ON NeoPool#Light==0 DO Power2 %value% ENDON
  ON NeoPool#Light==1 DO Power2 %value% ENDON

Backlog Rule1 5;Rule1 1

# File: neopoolcmd.be
#
# Add commands NPAux and NPVersion

# Neopool definitions
MBF_POWER_MODULE_REGISTER = 0x000C
MBF_POWER_MODULE_DATA = 0x000D
var MBF_RELAY_STATE = 0x010E

var MBF_PAR_TIMER_BLOCK_AUX1_INT1 = 0x04AC
var MBF_PAR_TIMER_BLOCK_AUX2_INT1 = 0x04BB
var MBF_PAR_TIMER_BLOCK_AUX3_INT1 = 0x04CA
var MBF_PAR_TIMER_BLOCK_AUX4_INT1 = 0x04D9
var PAR_TIMER_BLOCK_AUX = [
  MBF_PAR_TIMER_BLOCK_AUX1_INT1,
  MBF_PAR_TIMER_BLOCK_AUX2_INT1,
  MBF_PAR_TIMER_BLOCK_AUX3_INT1,
  MBF_PAR_TIMER_BLOCK_AUX4_INT1
]
var MBV_PAR_CTIMER_ALWAYS_ON      = 3
var MBV_PAR_CTIMER_ALWAYS_OFF     = 4

import string
import json

# NeoPool command class
class NeoPoolCommands
  var TEXT_OFF
  var TEXT_ON
  var TEXT_TOGGLE

  # string helper
  def ltrim(s)
    var i = 0 while(s[i]==' ') i += 1 end
    return string.split(s, i)[1]
  end
  def rtrim(s)
    return string.split(s, " ")[0]
  end
  def trim(s)
    return self.rtrim(self.ltrim(s));
  end

  def Param(payload, p2)
    var parm, res
    try
      parm = string.toupper(self.trim(payload))
    except ..
      parm = ""
    end
    if parm != ""
      if string.find(parm, 'OFF')>=0 || string.find(parm, self.TEXT_OFF)>=0 || string.find(parm, '0')>=0
        res = 0
      elif string.find(parm, 'ON')>=0 || string.find(parm, self.TEXT_ON)>=0 || string.find(parm, '1')>=0
        res = 1
      elif string.find(parm, p2)>=0 || string.find(parm, '2')>=0
        res = 2
      else
        res = -1
      end
    else
      res = nil
    end
    parm = nil
    tasmota.gc()
    return res
  end

  #- NPAux<x> OFF|0|ON|1 t (<x> = 1..4)
      0|OFF:   Switch aux x off
      1|ON:    Switch aux x on
      2|TOGGLE: Toggle Aux x
  -#
  def NPAux(cmd, idx, payload, payload_json, subcmd)
    var ctrl, parm

    if idx < 1 || idx > 4
      tasmota.resp_cmnd_error()
      return
    end
    parm = self.Param(payload, self.TEXT_TOGGLE)
    if parm != nil
      if 0 == parm
        ctrl = MBV_PAR_CTIMER_ALWAYS_OFF
      elif 1 == parm
        ctrl = MBV_PAR_CTIMER_ALWAYS_ON
      elif 2 == parm
        try
          ctrl = (compile("return "..tasmota.cmd(string.format("NPRead 0x%04X", MBF_RELAY_STATE)).find('NPRead', json.load('{"Data": "0x0000"}')).find('Data', 0))() >> (idx+2)) & 1 ? MBV_PAR_CTIMER_ALWAYS_OFF : MBV_PAR_CTIMER_ALWAYS_ON
        except ..
          tasmota.resp_cmnd_error()
          return
        end
      else
        tasmota.resp_cmnd_error()
        return
      end
      tasmota.cmd(string.format("NPWrite 0x%04X,%d", PAR_TIMER_BLOCK_AUX[idx-1], ctrl))
      tasmota.cmd("NPExec")
    else
      try
        ctrl = (compile("return "..tasmota.cmd(string.format("NPRead 0x%04X", MBF_RELAY_STATE)).find('NPRead', json.load('{"Data": "0x0000"}')).find('Data', 0))() >> (idx+2)) & 1
      except ..
        tasmota.resp_cmnd_error()
        return
      end
    end
    if subcmd != nil
      tasmota.resp_cmnd(string.format('{"%s":"%s"}', subcmd, ctrl == (parm != nil ? 4 : 0) ? self.TEXT_OFF : self.TEXT_ON))
    else
      tasmota.resp_cmnd(string.format('{"%s%d":"%s"}', cmd, idx, ctrl == (parm != nil ? 4 : 0) ? self.TEXT_OFF : self.TEXT_ON))
    end
  end

  # NPVersion
  def NPVersion(cmd)
    var verstr = ""
    for i: 0 .. 12
      tasmota.cmd(string.format("NPWrite 0x%04X,%d", MBF_POWER_MODULE_REGISTER, i*2))
      var data = compile("return "..tasmota.cmd(string.format("NPRead 0x%04X", MBF_POWER_MODULE_DATA)).find('NPRead', json.load('{"Data": "0x0000"}')).find('Data', 0))()
      verstr += string.char(data>>8 & 0xFF)
      verstr += string.char(data    & 0xFF)
    end
    var arr = ""
    for i: string.split(verstr,'\n')
      if arr != ""
        arr += ","
      end
      arr += '"'+i+'"'
    end
    tasmota.resp_cmnd(string.format('{"%s":[%s]}', cmd, arr))
  end

  def init()
    # get tasmota settings
    self.TEXT_OFF = tasmota.cmd("StateText1")['StateText1']
    self.TEXT_ON = tasmota.cmd("StateText2")['StateText2']
    self.TEXT_TOGGLE = tasmota.cmd("StateText3")['StateText3']
    # add commands
    tasmota.add_cmd('NPAux', / cmd, idx, payload -> self.NPAux(cmd, idx, payload))
    tasmota.add_cmd('NPVersion', / cmd -> self.NPVersion(cmd))
  end

  def deinit()
    # remove commands
    tasmota.remove_cmd('NPAux')
    tasmota.remove_cmd('NPVersion')
  end
end
neopoolcommands = NeoPoolCommands()

load("neopoolcmd.be")

# File: neopoolgui.be
#
# Add GUI elements for filtration control, light and aux relais

import webserver
import string

class NeoPoolButtonMethods : Driver

  #- method for adding elements to the main menu -#
  def web_add_main_button()

    def selected(value, comp)
      return comp == value ? 'selected=""' : ''
    end

    var html = '<p></p>'

    var speed = tasmota.cmd('NPFiltration').find('Speed', 'invalid')
    var mode = tasmota.cmd('NPFiltrationmode').find('NPFiltrationmode', 'invalid')
    if 'invalid' == speed && 'invalid' == mode
      html+= 'NeoPool device not available'
    else
      # Filtration mode/speed
      html+= '<table style="width:100%"><tbody><tr>'
      html+= '  <td style="width:50%;padding: 0 4px 0 4px;">'
      html+= '    <label for="mode"><small>Mode:</small></label>'
      html+= '    <select id="mode" name="mode">'
      html+= string.format('<option value="m_sv_manual"%s>Manual</option>', selected(mode, 'Manual'))
      html+= string.format('<option value="m_sv_auto"%s>Auto</option>', selected(mode, 'Auto'))
      html+= string.format('<option value="m_sv_heating"%s>Heating</option>', selected(mode, 'Heating'))
      html+= string.format('<option value="m_sv_smart"%s>Smart</option>', selected(mode, 'Smart'))
      html+= string.format('<option value="m_sv_intelligent"%s>Intelligent</option>', selected(mode, 'Intelligent'))
      html+= '    </select>'
      html+= '  </td>'
      html+= '  <td style="width:50%;padding: 0 4px 0 4px;">'
      html+= '    <label for="speed"><small>Speed:</label>'
      html+= '    <select id="speed" name="speed">'
      html+= string.format('<option value="m_sv_slow"%s>Slow</option>', selected(speed, '1'))
      html+= string.format('<option value="m_sv_medium"%s>Medium</option>', selected(speed, '2'))
      html+= string.format('<option value="m_sv_fast"%s>Fast</option>', selected(speed, '3'))
      html+= '    </select>'
      html+= '  </td>'
      html+= '</tr><tr></tr></tbody></table>'
      html+= '<script>'
      html+= 'document.getElementById("speed").addEventListener ("change",function(){la("&"+this.value+"=1");});'
      html+= 'document.getElementById("mode").addEventListener ("change",function(){la("&"+this.value+"=1");});'
      html+= '</script>'

      # Filtration button
      html+= '<table style="width:100%"><tbody><tr>'
      html+= '  <td style="width:100%">'
      html+= '    <button id="bn_filtration" name="bn_filtration" onclick="la(\'&m_sv_filtration=1\');">Filtration</button>'
      html+= '  </td>'
      html+= '</tr><tr></tr></tbody></table>'

      # Light button
      html+= '<table style="width:100%"><tbody><tr>'
      html+= '  <td style="width:100%">'
      html+= '    <button onclick="la(\'&m_sv_light=1\');">Light</button>'
      html+= '  </td>'
      html+= '</tr><tr></tr></tbody></table>'

      # Aux buttons
      html+= '<table style="width:100%"><tbody><tr>'
      html+= '  <td style="width:25%"><button onclick="la(\'&m_sv_aux=1\');">Aux1</button></td>'
      html+= '  <td style="width:25%"><button onclick="la(\'&m_sv_aux=2\');">Aux2</button></td>'
      html+= '  <td style="width:25%"><button onclick="la(\'&m_sv_aux=3\');">Aux3</button></td>'
      html+= '  <td style="width:25%"><button onclick="la(\'&m_sv_aux=4\');">Aux4</button></td>'
      html+= '</tr><tr></tr></tbody></table>'
    end

    webserver.content_send(html)
    html = nil
    speed = nil
    mode = nil
    tasmota.gc()
  end

  #- As we can add only one sensor method we will have to combine them besides all other sensor readings in one method -#
  def web_sensor()
    if webserver.has_arg("m_sv_filtration")
      tasmota.cmd("NPFiltration 2")
    end

    if webserver.has_arg("m_sv_slow")
      tasmota.cmd("NPFiltration 1,1")
    end
    if webserver.has_arg("m_sv_medium")
      tasmota.cmd("NPFiltration 1,2")
    end
    if webserver.has_arg("m_sv_fast")
      tasmota.cmd("NPFiltration 1,3")
    end

    if webserver.has_arg("m_sv_manual")
      tasmota.cmd("NPFiltrationmode 0")
    end
    if webserver.has_arg("m_sv_auto")
      tasmota.cmd("NPFiltrationmode 1")
    end
    if webserver.has_arg("m_sv_heating")
      tasmota.cmd("NPFiltrationmode 2")
    end
    if webserver.has_arg("m_sv_smart")
      tasmota.cmd("NPFiltrationmode 3")
    end
    if webserver.has_arg("m_sv_intelligent")
      tasmota.cmd("NPFiltrationmode 4")
    end

    if webserver.has_arg("m_sv_light")
      tasmota.cmd("NPLight 2")
    end

    if webserver.has_arg("m_sv_aux")
      tasmota.cmd("NPAux"+webserver.arg("m_sv_aux")+" TOGGLE")
    end
  end

  def init()
  end

  def deinit()
  end
end

neopool_driver = NeoPoolButtonMethods()
tasmota.add_driver(neopool_driver)

load("neopoolgui.be")

load("neopoolcmd.be")
load("neopoolgui.be")